SET NODOECHO
SET NOCOLOR
SET NOWARN
************************************************************************** 
** THIS FILE CALCULATES ELECTRICITY DNSP MULTILATERAL TFP FOR 2006-2024 **
** FOR ENX ONLY **********************************************************
**************************************************************************
** VARIABLES ARE IN ORDER: IDYEAR, TOTAL REVENUE, GWH, CONNECTION NO, ****
** MAXIMUM DEMAND, RATCHETED MAX DEMAND, CIRCUIT LENGTH, MINS OFF SUPPLY,* 
** PRICE MIN OFF-SUPPLY, OPEX, PRICE OF OPEX, OHSTLine, OHDNLine, ********
** UGSTCabl, UGDNCabl, MVA TRANSFORMERS EXCL FIRST STAGE, AUCOHST, *******
** AUCOHDN, AUCUGST, AUCUGDN, AUC TRANSFORMERS EXCL FIRST STAGE, *********
** Maximum Demand Index **************************************************
**************************************************************************
** WE USE LEONTIEF COST FUNCTION SHARES OF 0.11, 0.48, 0.15 AND 0.26 ON **
** OUTPUTS OF GWH, RATCHETED MAX DEMAND, CONNECTION NO, CIRCUIT LENGTH ***
** RELIABILITY IS INCLUDED AS 5th OUTPUT USING DNSP VCRs *****************
** INPUTS ARE OPEX, OH SUBTRANS MVAKMS, OH DIST MVAKMS, UG SUBTRANS MVAKMS, 
** UG DIST MVAKMS, MVA TRF CAP EXCL FIRST STAGE & OTHER ASSETS ***********
** WITH EXOGENOUS CAPITAL AUCs *******************************************
**************************************************************************
SMPL 1 19
read(ENXdata.csv) IDYear Revenue Energy CustNum MaxD RMDemand CircLen CustMOS PRCMOS Opex PrOpex &	
  OHSTLine OHDNLine UGSTCabl UGDNCabl SSTranf AUCOHST AUCOHDN AUCUGST AUCUGDN SSAUCTrn MDIndex / skiplines=1
genr VI1=Opex
genr R1=PrOpex
genr Q1=Energy
genr Q2=RMDemand
genr Q3=CustNum
genr Q4=CircLen
genr Q5=CustMOS
genr X2=OHSTLine
genr X3=OHDNLine
genr X4=UGSTCabl
genr X5=UGDNCabl
genr X6=SSTranf
genr VI2=AUCOHST
genr VI3=AUCOHDN
genr VI4=AUCUGST
genr VI5=AUCUGDN
genr VI6=SSAUCTrn
GENR GR=Revenue+PRCMOS*Q5/1000
GENR V1=GR*0.1079267
GENR V2=GR*0.4782655
GENR V3=GR*0.1522978
GENR V4=GR*0.2615100
GENR V5=-1*PRCMOS*Q5/1000
GENR X1=VI1/R1
DO #=1,5
GENR P#=V#/Q#
GENR SO#=V#/Revenue
STAT SO# / MEAN=SO#M
GENR LQ#=LOG(Q#)
STAT LQ# / MEAN=LQ#M
GENR LQ#L=LAG(LQ#)
GENR SO#L=LAG(SO#)
ENDO
GENR TC=VI1+VI2+VI3+VI4+VI5+VI6
GENR VK=VI2+VI3+VI4+VI5+VI6
DO #=1,6
GENR R#=VI#/X#
GENR SI#=VI#/TC
STAT SI# / MEAN=SI#M
GENR LX#=LOG(X#)
STAT LX# / MEAN=LX#M
GENR LX#L=LAG(LX#)
GENR SI#L=LAG(SI#)
ENDO
DO #=2,6
GENR SK#=VI#/VK
STAT SK# / MEAN=SK#M
GENR SK#L=LAG(SK#)
ENDO
SMPL 2 19
**********************************************************************
** MULTILATERAL CCD OUTPUT INDEX *************************************
**********************************************************************
GENR LNOI=0.5*((SO1+SO1M)*(LQ1-LQ1M)+(SO2+SO2M)*(LQ2-LQ2M)+(SO3+SO3M)*(LQ3-LQ3M)+ &
(SO4+SO4M)*(LQ4-LQ4M)+(SO5+SO5M)*(LQ5-LQ5M))-0.5*((SO1L+SO1M)*(LQ1L-LQ1M)+(SO2L+SO2M)*(LQ2L-LQ2M)+ &
(SO3L+SO3M)*(LQ3L-LQ3M)+(SO4L+SO4M)*(LQ4L-LQ4M)+(SO5L+SO5M)*(LQ5L-LQ5M))
GENR OI=EXP(LNOI)
**********************************************************************
** MULTILATERAL CCD INPUT INDEX **************************************
**********************************************************************
GENR LNII=0.5*((SI1+SI1M)*(LX1-LX1M)+(SI2+SI2M)*(LX2-LX2M)+(SI3+SI3M)*(LX3-LX3M)+ &
(SI4+SI4M)*(LX4-LX4M)+(SI5+SI5M)*(LX5-LX5M)+(SI6+SI6M)*(LX6-LX6M))- &
0.5*((SI1L+SI1M)*(LX1L-LX1M)+(SI2L+SI2M)*(LX2L-LX2M)+(SI3L+SI3M)*(LX3L-LX3M)+ &
(SI4L+SI4M)*(LX4L-LX4M)+(SI5L+SI5M)*(LX5L-LX5M)+(SI6L+SI6M)*(LX6L-LX6M))
GENR II=EXP(LNII)
**********************************************************************
** MULTILATERAL CCD CAPITAL INPUT INDEX ******************************
**********************************************************************
GENR LNKI=0.5*((SK2+SK2M)*(LX2-LX2M)+(SK3+SK3M)*(LX3-LX3M)+ &
(SK4+SK4M)*(LX4-LX4M)+(SK5+SK5M)*(LX5-LX5M)+(SK6+SK6M)*(LX6-LX6M))- &
0.5*((SK2L+SK2M)*(LX2L-LX2M)+(SK3L+SK3M)*(LX3L-LX3M)+ &
(SK4L+SK4M)*(LX4L-LX4M)+(SK5L+SK5M)*(LX5L-LX5M)+(SK6L+SK6M)*(LX6L-LX6M))
GENR KI=EXP(LNKI)
**********************************************************************
** MULTILATERAL OUTPUT CONTRIBUTIONS TO MTFP *************************
**********************************************************************
DO #=1,5
GENR OC#=0.5*(SO#+SO#M)*(LQ#-LQ#M)-0.5*(SO#L+SO#M)*(LQ#L-LQ#M)
ENDO
**********************************************************************
** MULTILATERAL INPUT CONTRIBUTIONS TO MTFP **************************
**********************************************************************
DO #=1,6
GENR IC#=-1*(0.5*(SI#+SI#M)*(LX#-LX#M)-0.5*(SI#L+SI#M)*(LX#L-LX#M))
ENDO
**********************************************************************
** MULTILATERAL CUMULATIVE INDEXES ***********************************
**********************************************************************
SMPL 1 19
GENR OUTIND=0.0
GENR INPIND=0.0
GENR KIND=0.0
GENR OUTIND(1)=1.0
GENR INPIND(1)=1.0
GENR KIND(1)=1.0
DO #=2,19
GENR OUTIND(#)=OUTIND(#-1)*OI(#)
GENR INPIND(#)=INPIND(#-1)*II(#)
GENR KIND(#)=KIND(#-1)*KI(#)
ENDO
GENR PRODIND=OUTIND/INPIND
DO #=1,5
GEN1 BASEO#=Q#(1)
GENR QB#=Q#/BASEO#
ENDO
DO #=1,6
GEN1 BASE#=X#(1)
GENR XB#=X#/BASE#
GENR PP#=OUTIND/XB#
ENDO
GENR PPK=OUTIND/KIND
PRINT IDYear OUTIND INPIND PRODIND PP1 PPK / WIDE
PRINT IDYear PP1 PPK PP2-PP6 / WIDE
PRINT IDYear QB1-QB5 MDIndex OUTIND / WIDE
PRINT IDYear XB1-XB6 KIND / WIDE
PRINT IDYear SO1-SO5 / WIDE
PRINT IDYear SI1-SI6 / WIDE
SMPL 2 19
PRINT IDYear OC1-OC5 / WIDE
PRINT IDYear IC1-IC6 / WIDE
SMPL 1 19
GENR T=TIME(0)
GENR LTFP=LOG(PRODIND)
GENR LQO=LOG(OUTIND)
GENR LQI=LOG(INPIND)
GENR LPP1=LOG(PP1)
GENR LPPK=LOG(PPK)
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2006-2024 *********************
**************************************************************************
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
SMPL 1 7
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2006-2012 *********************
**************************************************************************
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
SMPL 7 19
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2012-2024 *********************
**************************************************************************
GENR T=TIME(0)
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
STOP
